2011-08-01 Arnaud Charlet <charlet@adacore.com> * g-socket-dummy.adb, s-osinte-linux.ads, g-socket-dummy.ads, g-debuti.adb, g-tasloc.adb, g-debuti.ads, g-tasloc.ads, s-osinte-hpux.ads, g-sercom.adb, g-soliop-solaris.ads, g-sercom.ads, g-sptain.ads, g-curexc.ads, s-tasloc.adb, s-tasloc.ads, s-tataat.adb, g-ctrl_c.adb, a-reatim.adb, s-tataat.ads, g-dirope.adb, g-ctrl_c.ads, g-dirope.ads, g-boubuf.adb, g-calend.adb, g-boubuf.ads, g-souinf.ads, g-table.adb, g-bytswa-x86.adb, g-wispch.adb, g-io.adb, g-table.ads, g-wispch.ads, g-io.ads, g-memdum.adb, g-memdum.ads, g-busorg.adb, g-busorg.ads, g-regpat.adb, g-sothco-dummy.adb, g-encstr.adb, g-regpat.ads, g-sothco-dummy.ads, s-osinte-aix.ads, g-encstr.ads, g-sercom-mingw.adb, s-mastop-vms.adb, g-diopit.adb, g-diopit.ads, s-vxwext.adb, g-dyntab.adb, g-dyntab.ads, g-crc32.adb, g-sercom-linux.adb, g-crc32.ads, s-regpat.adb, g-flocon.ads, s-regpat.ads, g-stheme.adb, g-sestin.ads, s-taspri-posix-noaltstack.ads, g-soliop.ads, s-inmaop-posix.adb, g-locfil.ads, g-enblsp-vms-alpha.adb, g-socthi-dummy.adb, g-socthi-dummy.ads, gnat.ads, g-moreex.adb, g-moreex.ads, g-dynhta.adb, g-dynhta.ads, g-deutst.ads, g-htable.adb, g-cgicoo.adb, g-htable.ads, g-cgicoo.ads, a-interr.adb, g-socthi-vms.adb, g-socthi-vms.ads, g-hesora.adb, g-bubsor.adb, g-hesora.ads, g-bubsor.ads, g-md5.adb, g-md5.ads, s-intman-irix.adb, s-htable.adb, s-osinte-vms.adb, s-htable.ads, s-osinte-vms.ads, s-taprob.adb, g-bytswa.adb, g-bytswa.ads, s-osinte-solaris-posix.ads, a-suenco.adb, g-comver.adb, g-comver.ads, g-exctra.adb, s-osinte-solaris.adb, g-exctra.ads, s-osinte-irix.ads, s-osinte-solaris.ads, a-caldel-vms.adb, g-socthi-vxworks.adb, g-expect.adb, g-socthi-vxworks.ads, g-expect.ads, g-comlin.ads, g-heasor.adb, g-heasor.ads, g-traceb.adb, g-traceb.ads, g-decstr.adb, g-spipat.adb, g-decstr.ads, g-spipat.ads, s-mastop-tru64.adb, g-except.ads, g-thread.adb, g-hesorg.adb, g-thread.ads, g-hesorg.ads, g-expect-vms.adb, a-stuten.ads, g-spchge.adb, g-spchge.ads, g-u3spch.adb, g-u3spch.ads, g-spitbo.adb, g-spitbo.ads, s-osinte-dummy.ads, s-osinte-posix.adb, g-pehage.adb, g-pehage.ads, s-gloloc-mingw.adb, g-sha1.ads, s-traceb-hpux.adb, g-trasym-unimplemented.adb, g-trasym-unimplemented.ads, g-io_aux.adb, g-regexp.adb, g-io_aux.ads, g-socthi-mingw.adb, g-regexp.ads, s-osinte-hpux-dce.adb, g-socthi-mingw.ads, g-cgi.adb, s-osinte-hpux-dce.ads, g-cgi.ads, g-byorma.adb, g-boumai.ads, g-byorma.ads, a-caldel.adb, s-regexp.adb, s-regexp.ads, g-soliop-mingw.ads, g-sptavs.ads, s-osinte-tru64.ads, g-speche.adb, g-speche.ads, g-socthi.adb, g-stsifd-sockets.adb, g-socthi.ads, s-osinte-darwin.ads, i-vxwork-x86.ads, g-awk.adb, i-vxwork.ads, g-awk.ads, g-zspche.adb, g-zspche.ads, g-socket.adb, g-sptabo.ads, g-socket.ads, g-semaph.adb, g-semaph.ads, s-taspri-posix.ads, g-enblsp-vms-ia64.adb, g-cgideb.adb, g-cgideb.ads, g-sothco.adb, s-osinte-freebsd.ads, g-sothco.ads, g-catiio.adb, g-casuti.adb, g-catiio.ads, g-casuti.ads, g-trasym.adb, g-trasym.ads, s-casuti.adb, g-os_lib.adb, s-traceb-mastop.adb, g-busora.adb, s-interr-dummy.adb, g-busora.ads, g-enutst.ads, s-os_lib.adb, a-tasatt.adb, s-osinte-mingw.ads: Update to GPLv3 run-time license. Use GNAT instead of GNARL. 2011-08-01 Bob Duff <duff@adacore.com> * a-cdlili.ads, a-cihama.ads, a-coinve.ads, a-ciorse.ads, a-coorma.ads, a-cidlli.ads, a-ciormu.ads, a-cihase.ads, a-cohama.ads, a-coorse.ads, a-ciorma.ads, a-coormu.ads, a-convec.ads, a-cohase.ads: Minor reformatting. 2011-08-01 Yannick Moy <moy@adacore.com> * debug.adb (d.D) reverve flag for the SPARK mode (d.E) reverve flag for SPARK generation mode (d.F) reverve flag for Why generation mode * opt.ads, opt.adb (ALFA_Mode, ALFA_Through_SPARK_Mode, ALFA_Through_Why_Mode, Formal_Verification_Mode, SPARK_Mode): New functions which return True when the corresponding modes are set (Formal_Language): return "spark" or "alfa" when in formal verification mode. * sem_util.ads, sem_util.adb (Formal_Error_Msg): new wrapper on Error_Msg to prefix the error message with a tag giving the formal language (Formal_Error_Msg_N): new wrapper on Error_Msg_N to prefix the error message with a tag giving the formal language * sem_ch5.adb (Analyze_Block_Statement): issue error in formal mode on block statement (Analyze_Case_Statement): issue error in formal mode on case statement with a single "others" case alternative (Analyze_Exit_Statement): issue errors in formal mode on exit statements which do not respect SPARK restrictions (Analyze_Goto_Statement): issue error in formal mode on goto statement (Check_Unreachable_Code): always issue an error (not a warning) in formal mode on unreachable code (concerns both code after an infinite loop and after an unconditional jump, both not allowed in SPARK) * sem_ch6.adb (Analyze_Return_Statement): add call to Set_Return_Present for a procedure containing a return statement (already done for functions in Analyze_Function_Return) (Analyze_Function_Return): issue error in formal mode on extended return or if return is not last statement in function (Check_Missing_Return): issue error in formal mode if function does not end with return or if procedure contains a return * sem_ch8.ads, sem_ch8.adb (Has_Loop_In_Inner_Open_Scopes): new function to detect if there is an inner scope of its parameter S which is a loop. 2011-08-01 Thomas Quinot <quinot@adacore.com> * sem_ch6.ads: Minor reformatting. From-SVN: r177040
272 lines
9.0 KiB
Ada
272 lines
9.0 KiB
Ada
------------------------------------------------------------------------------
|
|
-- --
|
|
-- GNAT COMPILER COMPONENTS --
|
|
-- --
|
|
-- G N A T . S E R I A L _ C O M M U N I C A T I O N S --
|
|
-- --
|
|
-- B o d y --
|
|
-- --
|
|
-- Copyright (C) 2007-2010, AdaCore --
|
|
-- --
|
|
-- GNAT is free software; you can redistribute it and/or modify it under --
|
|
-- terms of the GNU General Public License as published by the Free Soft- --
|
|
-- ware Foundation; either version 3, or (at your option) any later ver- --
|
|
-- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
|
|
-- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
|
|
-- or FITNESS FOR A PARTICULAR PURPOSE. --
|
|
-- --
|
|
-- As a special exception under Section 7 of GPL version 3, you are granted --
|
|
-- additional permissions described in the GCC Runtime Library Exception, --
|
|
-- version 3.1, as published by the Free Software Foundation. --
|
|
-- --
|
|
-- You should have received a copy of the GNU General Public License and --
|
|
-- a copy of the GCC Runtime Library Exception along with this program; --
|
|
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
|
|
-- <http://www.gnu.org/licenses/>. --
|
|
-- --
|
|
-- GNAT was originally developed by the GNAT team at New York University. --
|
|
-- Extensive contributions were provided by Ada Core Technologies Inc. --
|
|
-- --
|
|
------------------------------------------------------------------------------
|
|
|
|
-- This is the Windows implementation of this package
|
|
|
|
with Ada.Unchecked_Deallocation; use Ada;
|
|
with Ada.Streams; use Ada.Streams;
|
|
|
|
with System; use System;
|
|
with System.Communication; use System.Communication;
|
|
with System.CRTL; use System.CRTL;
|
|
with System.Win32; use System.Win32;
|
|
with System.Win32.Ext; use System.Win32.Ext;
|
|
|
|
package body GNAT.Serial_Communications is
|
|
|
|
-- Common types
|
|
|
|
type Port_Data is new HANDLE;
|
|
|
|
C_Bits : constant array (Data_Bits) of Interfaces.C.unsigned := (8, 7);
|
|
C_Parity : constant array (Parity_Check) of Interfaces.C.unsigned :=
|
|
(None => NOPARITY, Odd => ODDPARITY, Even => EVENPARITY);
|
|
C_Stop_Bits : constant array (Stop_Bits_Number) of Interfaces.C.unsigned :=
|
|
(One => ONESTOPBIT, Two => TWOSTOPBITS);
|
|
|
|
-----------
|
|
-- Files --
|
|
-----------
|
|
|
|
procedure Raise_Error (Message : String; Error : DWORD := GetLastError);
|
|
pragma No_Return (Raise_Error);
|
|
|
|
-----------
|
|
-- Close --
|
|
-----------
|
|
|
|
procedure Close (Port : in out Serial_Port) is
|
|
procedure Unchecked_Free is
|
|
new Unchecked_Deallocation (Port_Data, Port_Data_Access);
|
|
|
|
Success : BOOL;
|
|
|
|
begin
|
|
if Port.H /= null then
|
|
Success := CloseHandle (HANDLE (Port.H.all));
|
|
Unchecked_Free (Port.H);
|
|
|
|
if Success = Win32.FALSE then
|
|
Raise_Error ("error closing the port");
|
|
end if;
|
|
end if;
|
|
end Close;
|
|
|
|
----------
|
|
-- Name --
|
|
----------
|
|
|
|
function Name (Number : Positive) return Port_Name is
|
|
N_Img : constant String := Positive'Image (Number);
|
|
begin
|
|
return Port_Name ("COM" & N_Img (N_Img'First + 1 .. N_Img'Last) & ':');
|
|
end Name;
|
|
|
|
----------
|
|
-- Open --
|
|
----------
|
|
|
|
procedure Open
|
|
(Port : out Serial_Port;
|
|
Name : Port_Name)
|
|
is
|
|
C_Name : constant String := String (Name) & ASCII.NUL;
|
|
Success : BOOL;
|
|
pragma Unreferenced (Success);
|
|
|
|
begin
|
|
if Port.H = null then
|
|
Port.H := new Port_Data;
|
|
else
|
|
Success := CloseHandle (HANDLE (Port.H.all));
|
|
end if;
|
|
|
|
Port.H.all := CreateFileA
|
|
(lpFileName => C_Name (C_Name'First)'Address,
|
|
dwDesiredAccess => GENERIC_READ or GENERIC_WRITE,
|
|
dwShareMode => 0,
|
|
lpSecurityAttributes => null,
|
|
dwCreationDisposition => OPEN_EXISTING,
|
|
dwFlagsAndAttributes => 0,
|
|
hTemplateFile => 0);
|
|
|
|
if Port.H.all = 0 then
|
|
Raise_Error ("cannot open com port");
|
|
end if;
|
|
end Open;
|
|
|
|
-----------------
|
|
-- Raise_Error --
|
|
-----------------
|
|
|
|
procedure Raise_Error (Message : String; Error : DWORD := GetLastError) is
|
|
begin
|
|
raise Serial_Error with Message & " (" & DWORD'Image (Error) & ')';
|
|
end Raise_Error;
|
|
|
|
----------
|
|
-- Read --
|
|
----------
|
|
|
|
overriding procedure Read
|
|
(Port : in out Serial_Port;
|
|
Buffer : out Stream_Element_Array;
|
|
Last : out Stream_Element_Offset)
|
|
is
|
|
Success : BOOL;
|
|
Read_Last : aliased DWORD;
|
|
|
|
begin
|
|
if Port.H = null then
|
|
Raise_Error ("read: port not opened", 0);
|
|
end if;
|
|
|
|
Success :=
|
|
ReadFile
|
|
(hFile => HANDLE (Port.H.all),
|
|
lpBuffer => Buffer (Buffer'First)'Address,
|
|
nNumberOfBytesToRead => DWORD (Buffer'Length),
|
|
lpNumberOfBytesRead => Read_Last'Access,
|
|
lpOverlapped => null);
|
|
|
|
if Success = Win32.FALSE then
|
|
Raise_Error ("read error");
|
|
end if;
|
|
|
|
Last := Last_Index (Buffer'First, size_t (Read_Last));
|
|
end Read;
|
|
|
|
---------
|
|
-- Set --
|
|
---------
|
|
|
|
procedure Set
|
|
(Port : Serial_Port;
|
|
Rate : Data_Rate := B9600;
|
|
Bits : Data_Bits := CS8;
|
|
Stop_Bits : Stop_Bits_Number := One;
|
|
Parity : Parity_Check := None;
|
|
Block : Boolean := True;
|
|
Timeout : Duration := 10.0)
|
|
is
|
|
Success : BOOL;
|
|
Com_Time_Out : aliased COMMTIMEOUTS;
|
|
Com_Settings : aliased DCB;
|
|
|
|
begin
|
|
if Port.H = null then
|
|
Raise_Error ("set: port not opened", 0);
|
|
end if;
|
|
|
|
Success := GetCommState (HANDLE (Port.H.all), Com_Settings'Access);
|
|
|
|
if Success = Win32.FALSE then
|
|
Success := CloseHandle (HANDLE (Port.H.all));
|
|
Port.H.all := 0;
|
|
Raise_Error ("set: cannot get comm state");
|
|
end if;
|
|
|
|
Com_Settings.BaudRate := DWORD (Data_Rate_Value (Rate));
|
|
Com_Settings.fParity := 1;
|
|
Com_Settings.fBinary := Bits1 (System.Win32.TRUE);
|
|
Com_Settings.fOutxCtsFlow := 0;
|
|
Com_Settings.fOutxDsrFlow := 0;
|
|
Com_Settings.fDsrSensitivity := 0;
|
|
Com_Settings.fDtrControl := DTR_CONTROL_DISABLE;
|
|
Com_Settings.fOutX := 0;
|
|
Com_Settings.fInX := 0;
|
|
Com_Settings.fRtsControl := RTS_CONTROL_DISABLE;
|
|
Com_Settings.fAbortOnError := 0;
|
|
Com_Settings.ByteSize := BYTE (C_Bits (Bits));
|
|
Com_Settings.Parity := BYTE (C_Parity (Parity));
|
|
Com_Settings.StopBits := BYTE (C_Stop_Bits (Stop_Bits));
|
|
|
|
Success := SetCommState (HANDLE (Port.H.all), Com_Settings'Access);
|
|
|
|
if Success = Win32.FALSE then
|
|
Success := CloseHandle (HANDLE (Port.H.all));
|
|
Port.H.all := 0;
|
|
Raise_Error ("cannot set comm state");
|
|
end if;
|
|
|
|
-- Set the timeout status
|
|
|
|
if Block then
|
|
Com_Time_Out := (others => 0);
|
|
else
|
|
Com_Time_Out :=
|
|
(ReadTotalTimeoutConstant => DWORD (1000 * Timeout),
|
|
others => 0);
|
|
end if;
|
|
|
|
Success :=
|
|
SetCommTimeouts
|
|
(hFile => HANDLE (Port.H.all),
|
|
lpCommTimeouts => Com_Time_Out'Access);
|
|
|
|
if Success = Win32.FALSE then
|
|
Raise_Error ("cannot set the timeout");
|
|
end if;
|
|
end Set;
|
|
|
|
-----------
|
|
-- Write --
|
|
-----------
|
|
|
|
overriding procedure Write
|
|
(Port : in out Serial_Port;
|
|
Buffer : Stream_Element_Array)
|
|
is
|
|
Success : BOOL;
|
|
Temp_Last : aliased DWORD;
|
|
|
|
begin
|
|
if Port.H = null then
|
|
Raise_Error ("write: port not opened", 0);
|
|
end if;
|
|
|
|
Success :=
|
|
WriteFile
|
|
(hFile => HANDLE (Port.H.all),
|
|
lpBuffer => Buffer'Address,
|
|
nNumberOfBytesToWrite => DWORD (Buffer'Length),
|
|
lpNumberOfBytesWritten => Temp_Last'Access,
|
|
lpOverlapped => null);
|
|
|
|
if Success = Win32.FALSE
|
|
or else Stream_Element_Offset (Temp_Last) /= Buffer'Length
|
|
then
|
|
Raise_Error ("failed to write data");
|
|
end if;
|
|
end Write;
|
|
|
|
end GNAT.Serial_Communications;
|